Software unter Windows für Screenshot, Uhrzeit als Wasserzeichen und FTP Upload gesucht

#NoTrayIcon
#include <ScreenCapture.au3>
#include <GDIPlus.au3>
#include <Date.au3>
#include <FTPEx.au3>

$FTP_SERVER = "ftp.domain.tld"  
$FTP_USER = "USERNAME"  
$FTP_PASS = "PASSWORD"  
$FTP_PASSIVE = 1
$FTP_FILEPATH = "screenshot.png"  

; =============================
; local output path
$output = @TempDir & "\screenshot.png"  
; Zeitstempel
$timestamp = _DateTimeFormat(_NowCalc(),0)
; GDI startup
_GDIPlus_Startup()
; take screenshot
$hBMP = _ScreenCapture_Capture()
; create image resource
$hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBMP)
; create graphics resource
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage)
; create font family
$hFamily = _GDIPlus_FontFamilyCreate("Arial")  
; create font
$hFont = _GDIPlus_FontCreate($hFamily,16,0,3)
; string format definitions
$hFormat = _GDIPlus_StringFormatCreate(0x4000)
; create brushes
$hBrushBlackTransparent = _GDIPlus_BrushCreateSolid(0xA0000000)
$hBrushWhite = _GDIPlus_BrushCreateSolid(0xFFFFFFFF)
; layout object
$tLayout = _GDIPlus_RectFCreate(10,10)
; measure actual size of text
$aInfo = _GDIPlus_GraphicsMeasureString($hGraphic,$timestamp,$hFont,$tLayout,$hFormat)
; create transparent black rect for background
_GDIPlus_GraphicsFillRect($hGraphic,$aInfo.X,$aInfo.Y,$aInfo.Width,$aInfo.Height,$hBrushBlackTransparent)
; draw string
_GDIPlus_GraphicsDrawStringEx($hGraphic,$timestamp,$hFont,$aInfo,$hFormat,$hBrushWhite)
; save to file
_GDIPlus_ImageSaveToFile($hImage,$output)
; cleanup
_GDIPlus_BrushDispose($hBrushBlackTransparent)
_GDIPlus_BrushDispose($hBrushWhite)
_GDIPlus_StringFormatDispose($hFormat)
_GDIPlus_FontDispose($hFont)
_GDIPlus_FontFamilyDispose($hFamily)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_ImageDispose($hImage)
; GDI shutdown
_GDIPlus_Shutdown()

; FTP Session ---------------------
$hFTP = _FTP_Open("ftpsession")  
$hConn = _FTP_Connect($hFTP,$FTP_SERVER,$FTP_USER,$FTP_PASS,$FTP_PASSIVE)
_FTP_FilePut($hConn,$output,$FTP_FILEPATH)
_FTP_Close($hFTP)