supertux
Mar 26, 2024
view489
view3
0
Goto Top

Excel VBA Filter auf alle Arbeitsblätter

GermansolvedQuestionVB for Applications
Hallo,

ich habe derzeit in Excel 17 Arbeitsblätter, die alle die gleichen Spaltenamen besitzen.

Spalte1 Spalte2 Spalte3 Spalte4 Spalte5 Spalte6 Spalte7 Spalte8 Spalte9

Ich aktivieren den Autofilter und möchte gerne in einem zufälligen Arbeitsblatt ein Filterkriterium
aus den Spalte1 - Spalte9 auswählen. Das ausgewählt Filterkriterium soll nun auf alle Arbeitsblätter,
bis auf Tabelle Übersicht angewandt werden.

---
supertux
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 81521344749

Url: https://administrator.de/contentid/81521344749

Printed on: April 27, 2024 at 06:04 o'clock

3 Comments
Latest comment
Goto Top
Member: Delta9
Delta9 Mar 26, 2024 at 15:32:20 (UTC)
Goto Top
Hallo supertux,

und wie hast du das realisiert?

Schon mal vielen Dank für deine Anleitung.

Gruß

Delta
Mitglied: 12168552861
Solution 12168552861 Mar 26, 2024 updated at 16:12:43 (UTC)
Goto Top
Sub AktuellenFilterAufSheetsKopieren()
    Dim ws As Worksheet, f As Integer
    If ActiveSheet.AutoFilter.Filters.Count = 0 Then Exit Sub
    With ActiveSheet.AutoFilter.Filters
        For Each ws In Sheets
            If Not ws.Name = ActiveSheet.Name And Not ws.Name = "Übersicht" Then  
                For f = 1 To .Count
                    With .Item(f)
                        If .On Then
                            If .Operator Then
                                If .Operator = xlFilterValues Then
                                  ws.UsedRange.AutoFilter Field:=f, Operator:=.Operator, Criteria1:=.Criteria1
                                Else
                                  ws.UsedRange.AutoFilter Field:=f, Operator:=.Operator, Criteria1:=.Criteria1, Criteria2:=.Criteria2
                                End If
                            Else
                                ws.UsedRange.AutoFilter Field:=f, Criteria1:=.Criteria1
                            End If
                        Else
                            ws.UsedRange.AutoFilter Field:=f
                        End If
                    End With
                Next
            End If
        Next
    End With
End Sub

Gruß pp.
Member: supertux
supertux Mar 26, 2024 at 17:04:14 (UTC)
Goto Top
Hallo pp,

vielen Dank für den Code, funktioniert face-smile

@Delta9 mit dem VBA-Code.

---
supertux
GermansolvedQuestionVB for Applications